Bagaimana Cara Menghitung Karakter di Excel

Bagaimana Cara Menghitung Karakter di Excel

Posted on

Setelah tutorial Cara Menghitung Karakter di Excel ini Anda akan dapat menghitung total karakter dalam sebuah cell atau range, atau kombinasi karakter tertentu dalam cell atau range dengan case sensitive dan insensitive alternatif. Pengaturan yang diperoleh dalam tutorial ini adalah dasar yang sangat baik untuk pemecahan masalah Excel lebih lanjut yang kreatif.

Bagaimana Cara Menghitung Karakter di Excel

Jika Anda ingin belajar cara menghitung karakter di Excel, Anda bisa menggunakan function LEN, menggunakan formula =LEN(cell) untuk menghitung total karakter yang ada di dalam sebuah cell, atau kombinasi dari function SUMPRODUCT and LEN untuk menghitung total karakter dalam sebuah range dengan formula =SUMPRODUCT(LEN(range)). Sebagai tambahan, untuk menghitung karakter yang lebih spesifik di dalam sebuah cell atau range dan kombinasi karakter spesifik dalam sebuah cell atau range akan kami jelaskan secara detail.

  1. Menghitung total karakter dalam sebuah cell
  2. Menghitung total karakter dalam sebuah range
  3. Menghitung karakter spesifik dalam sebuah cell
  4. Menghitung karakter spesifik dalam sebuah range
  5. Menghitung kombinasi karakter spesifik dalam sebuah cell dan range

Menghitung Total Karakter Dalam Sebuah Cell

Total karakter dalam sebuah cell dapat mudah ditemukan dengan menggunakan function LEN. Function ini hanya memiliki satu argumen, referensi cell atau teks, dimana jumlah karakter akan dihitung:

=LEN(text)

=LEN(B3)

Function ini akan menhitung total karakter dalam sebuah cell, termasuk spasi, tanda baca, simbol, meskipun mereka muncul dalam beberapa string.

Menghitung karakter dalam sebuah cell

Jika kita ingin menghitung karakter dalam sebuah cell tanpa ingin spasi terhitung, maka gunakan kombinasi LEN dan juga SUBTITUTE. Mari kita lihat pada contoh di bawah ini, formula untuk menghitung total karakater dalam sebuah cell tanpa spasi terhitung:

Menghitung Karakter Dalam Sebuah Cell Tanpa Spasi Terhitung

=LEN(SUBSTITUTE(B3;” “;””))

Function SUBITUTE merubah sebuah cell karakter/teks dengan karakter/teks lainnya. Jika kita ingin menghitungnya tanpa spasi maka gunakan function ini, spasi akan tidak dihitung lagi, ini akan menghilangkan spasi dengan sebuah string yang kosong. Setelah SUBTITUTE teks function akan terlihat seperti di bawah ini:

=LEN(“MatahariTerbit”)

Setelah itu, akan mudah menghitung total karakter dengan LEN dengan hasil perhitungannya adalah 14.

Menghitung Karakter Di Dalam Sebuah Range

Untuk menghitung jumlah karakter di dalam sebuah range, kita membutuhkan 2 function, SUMPRODUCT dan LEN. Penggunaan function SUMPRODUCT adalah solusi yang elegan ketika berhadapan dengan beberapa cell ataupun arrays. Coba kita lihat pada contoh di bawah ini:

=SUMPRODUCT(LEN(range))

=SUMPRODUCT(LEN(B4:B7))

Menghitung karakter dalam sebuah range

Function LEN berkaitan dengan cell, tetapi untuk range cell penggunaan function Cell yang dijumlahkan (=LEN(B4)+LEN(B5)+LEN(B6)+LEN(B7)) bukanlah solus yang terbaik dimana kita bisa menggunakan banyak ranges. Sedangkan, function SUMPRODUCT merangkum hasil fungsi LEN dalam range yang ditentukan.

Dalam evaluasi formula, hasilnya akan terlihat sebagai berikut:

=SUMPRODUCT({15;18;14;22})

Hasil penjumlahan pada array tersebut sesuai dengan penggunaan function LEN dari hasil penjumlahan masing-masing cell yang kita sorot B4:B7, akan menghasilakan nilai 69.

Alternatif lainnya adalah dengan menggabungkan function SUM dan LEN. Penulisan formulanya hampir sama, hanya ada pada perbedaan penulisan dengan formula tersebut menjadi sebuah array ( bisa menggunakan shortcut CTRL+SHIFT+ENTER ). Untuk lebih jelasnya silakan diliihat pada contoh di bawah ini:

{=SUM(LEN(B4:B7))}

Menghitung karakter dalam sebuah range dengan bantuan function SUM

Menghitung Karakter Spesifik Dalam Sebuah Cell

Selain menghitung jumlah total karakter, ada juga cara untuk menghitung karakter spesifik yang ada di dalam sebuah cell. Akan kami berikan contohnya untuk cara menghitung karakter spesifik dalam sebuah cell. Kita akan menggunakan fungsi LEN dan SUBTITUTE.

Caranya hampir mirip seperti sebelumnya kita menghitung total karakter dalam sebuah cell. Silakan dilihat pada contoh di bawah ini. Syntaxnya akan seperti ini:

=LEN(cell)-LEN(SUBSTITUTE(cell;character;””))

Mari kita gunakan pada contoh kasus sebenarnya di bawah ini:

=LEN(B3)-LEN(SUBSTITUTE(B3;”a”;””))

Menghitung karakter spesifik dalam sebuah cell

Kami jelaskan secara singkat logika dari kombinasi fungsi tersebut. Jumlah karakter total dalam cell B3 dikurangi dengan nomor karakter dalam cell yang sama, tetapi tanpa karakter spesifik yang ingin kita hitung. Seperti disebutkan dalam tutorial 1, function SUBSTITUTE digunakan untuk mengubah string dalam cell yang ditentukan dalam bentuk tanpa karakter tertentu, menggantikan karakter itu dengan string kosong.

=SUBSTITUTE(cell;”character”;””)

Dapat dilihat pada hasil akhir bahwa function tidak menghitung karakter huruf besar karena fungsi LEN peka huruf besar-kecil. Solusi untuk menghitung karakter tanpa kriteria case-sensitive adalah penggunaan fungsi UPPER / LOWER, di mana semua karakter akan diterjemahkan ke huruf besar / kecil dan fungsi akan menjadi case-sensitive.

Pada contoh di bawah ini, function LOWER disatukan ke fungsi SUBSTITUTE, mengubah semua string dalam sel B3 menjadi huruf kecil, karena kriteria didefinisikan sebagai huruf kecil, “a”

=LEN(cell)-LEN(SUBSTITUTE(LOWER(cell);”lowercase character”;””))

=LEN(B3)-LEN(SUBSTITUTE(LOWER(B3);”t”;””))

Menghitung karakter spesifik besar dan kecil

Cara lain untuk membuat function non-case sensitive adalah menggunakan double function SUBTITUTE dan dikombinasikan dengan function LEN. Pada contoh selanjutnya, menghitung karakter akan pada cell tertentu, karena kadang-kadang tidak praktis untuk menulis setiap kali menghitung karakter dalam sebuah formula, terutama apabila Anda berurusan dengan range dan formula yang kompleks.

Formula dengan double function SUBTITUTE:

=LEN(cell)-LEN(SUBSTITUTE(SUBSTITUTE(cell;LOWER(character);””);UPPER(character);””))

=LEN(B3)-LEN(SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);””);UPPER(B6);””))

Menghitung karakter dengan double function SUBTITUTE

Formula tersebut terlihat sangat kompleks, tetapi semua akan jelas setelah dijelaskan. Mari kita bedah satu per satu:

=SUBSTITUTE(B3;LOWER(B6);””)

=SUBSTITUTE(“Matahari Terbit ”;LOWER(“T”);””)

Function LOWER diletakkan untuk mengubah penghitungan karakter menjadi huruf kecil, dan kemudian function SUBITUTE mengganti huruf kecil menjadi string kosong.

Pada langkah selanjutnya, tujuannya adalah mengeliminasi perhitungan huruf besar pada text/cell yang dipilih. Ini bisa diselesaikan dengan function SUBTITUTE berjaring:

=SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);””);UPPER(B6);””)

Menghitung Karakter Spesifik Dalam Sebuah Range

Ketika kita berhubungan dengan RANGE atau ARRAYS , kita perlu menggunakan function SUMPRODUCT untuk dikombinasikan dengan function lainnya. Untuk menghitung spesifik karakter dalam sebuah range, untuk case sensitive maka akan menggunakan kombinasi dari 3 function yaitu SUMPRODUCT, LEN dan SUBTITUTE. Jika bukan case sensitive maka perlu penambahan formula dengan menggunakan UPPER/LOWER.

Pertama-tama kami akan menjelaskan cara menghitung jumlah karakter “T” pada range yang kita pilih (versi case sensitive). Rumus ini hampir mirip dengan rumus yang menjelaskan perhitungan karakter. Perbedaannya adalah function LEN ganda di dalam function SUMPRODUCT dan di dalam area yang akan dihitung:

=SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(B3:B6;B9;””)))

Menghitung karakter spesifik dalam sebuah range

Untuk karakter case-insensitive menghitung pada range yang akan dipilih. Kita bisa gunakan function yang dijelaskan secara detail pada perhitungan karakter case-insensitive. Gandakan function LEN di dalam SUMPRODUCT function dan ganti cell dengan range cell, silakan dilihat pada contoh di bawah ini:

=SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(SUBSTITUTE(B3:B6;LOWER(B9);””);UPPER(B9);””)))

Menghitung karakter dalam sebuah range pada case-insensitive

Ingat, ketika kamu bertemu dengan cell range, kamu harus menggunakan funtion SUMPRODUCT. Pada case-sensitive function yang diperlukan adalah SUMPRODUCT, LEN dan SUBTITUTE, dan pada case-insensitive function yang diperlukan SUMPRODUCT, LEN, SUBTITUTE dan LOWER/UPPER.

Menghitung Kombinasi Spesifik Karakter Sebuah Cell atau Range

Ada juga kemungkinan untuk menghitung kombinasi karakter tertentu dalam cell atau range yang ditentukan. Pada poin tutorial sebelumnya, kami membahas penghitungan karakter tunggal dalam cell atau range dengan alternatif case sensitif / tidak sensitif. Formula untuk menghitung kombinasi karakter adalah sama, hanya saja kita harus membaginya dengan jumlah karakter dalam kombinasi karakter.

Mari kita lihat pada contoh di bawah ini, untuk menghitung kombinasi karakter tertentu dalam sel (versi case-sensitive):

=(LEN(B3)-LEN(SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);””);UPPER(B6);””)))/LEN(B6)

Menghitung karakter spesifik dalam sebuah cell

Logika sama dengan menghitung karakter tunggal, hanya kami harus membagi formula reguler dengan jumlah karakter spesifik yang kami hitung, dengan mudah menggunakan rumus: LEN (“ta”). Tanpa membagi rumus dengan LEN (“ta”), hasilnya akan dikalikan dengan jumlah karakter dalam kombinasi karakter (dalam contoh kita dengan 2, karena “ta” memiliki dua karakter)

Untuk menghitung kombinasi karakter tertentu dalam formula cell (versi case-sensitive) akan terlihat seperti:

=(LEN(B3)-LEN(SUBSTITUTE(B3;B6;””)))/LEN(B6)

Menghitung kombinasi karakter dalam sebuah range memiliki logika yang sama dengan menghitung kombinasi karakter tunggal, dan untuk karakter case-sensitive formulanya akan seperti ini:

=(SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(SUBSTITUTE(B3:B6;LOWER(B9);””);UPPER(B9);””))))/LEN(B9)

Menghitung kombinasi karakter dalam sebuah range

Jika kita ingin menghitung case-insensitive maka formulanya akan seperti di bawah ini:

=(SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(B3:B6;B9;””))))/LEN(B9)

Demikianlah tutorial Cara Menghitung Karakter di Excel, semoga bermanfaat.